RF Powers

Init

Needs["Controls`LinearControl`"]

$TextStyle={FontFamily->"Helvetica",FontSize->13};

plotopt=Sequence@@{GridLines->Automatic,Frame->True,FrameStyle->Thickness[0.0025],BaseStyle->{FontSize->12}};

plotoptn[n_Integer?(#>0∧#<6&)]:=Sequence@@{GridLines->Automatic,Frame->True,FrameStyle->Thickness[0.0025],PlotStyle->Take[{Purple,Brown,Darker[Green],Blue,Red},-n],BaseStyle->{FontSize->12}};
plotoptn[n_Integer?(#≤0∨#≥6&)]:=plotopt

mylegend[labels_List,pos_:Right]:={Placed[LineLegend[labels,LabelStyle->{FontSize->11},LegendMargins->2,LegendFunction->(Framed[#,Background->White]&)],pos]}

Modulation

Calibration

alog 41889 and 41435

rf9cal=(0.191/(dbm2v[23.6]));(* rad/V *)
rf45cal=(0.259/(dbm2v[27]));(* rad/V *)

Formulae

dbm2v[x_]:=(Sqrt[(10^(x/10)) 50 1*^-3])
rad9[x_]:=rf9cal dbm2v[x]
rad45[x_]:=rf45cal dbm2v[x]
pwr9[x_]:=2((BesselJ[1,rad9[x]])^2)
pwr45[x_]:=2((BesselJ[1,rad45[x]])^2)
pwrcr[x_,y_]:=((BesselJ[0,rad9[x]])^2)((BesselJ[0,rad45[y]])^2)

Calculations

Sidebands

rad45[24]
rad9[20.4]
pwr45[24]
pwr9[20.4]

Carrier

((pwrcr[20.4,24+3])/(pwrcr[20.4,24]))-1
((pwrcr[20.4+3,24])/(pwrcr[20.4,24]))-1

Series[(((BesselJ[0,γ])^2)/((BesselJ[0,γ1])^2)),{γ,0,2},{γ1,0,2}]//Normal//Simplify

Sideband/Carrier Ratio from measured powers

c : modulation index ratio
p0: carrier power
p1: RF modulation sideband power

Solve[{p0+ p1==m1,p0+(c^2) p1==m2},{p0,p1}]
Simplify[(p1/(p0+p1))/.%]

Solve[{((BesselJ[0,γ1])^2)p0+2((BesselJ[1,γ1])^2)p1==m1,((BesselJ[0,γ2])^2)p0+2((BesselJ[1,γ2])^2) p1==m2},{p0,p1}]
Simplify[((2((BesselJ[1,γ1])^2)p1)/(((BesselJ[0,γ1])^2)p0+2((BesselJ[1,γ1])^2)p1))/.%]

ratio[r_,c_]:=((r-1)/((c^2)-1))(* r: measurement ratio, c: modulation index ratio *)
ratio[r_,γ1_,γ2_]:=((r (((BesselJ[0,γ1])^2)/((BesselJ[0,γ2])^2))- 1)/((((BesselJ[0,γ1])^2)/((BesselJ[0,γ2])^2))(( ((BesselJ[1,γ2])^2))/((BesselJ[1,γ1])^2))-1))

Data

names={"Input power (W)", "9MHz modulation (dBm)","45MHz modulation (dBm)", "REFL_A (mW)", "REFL_B (mW)", "POP_LF", "POP_A_NSUM","POP_B_NSUM","AS_C_NSUM (W)","OMC_A_NSUM (W)","OMC_B_NSUM (W)","TR_X_A","TR_X_B","TR_Y_A","TR_Y_B"};

Measurements on May 12 2021, 23:44:35 UTC

alog 58946;

dir1="E:\\OneDrive\\Documents\\Mathematica\\RFpower\\13May2021\\";
(*files={"imcpwr.txt","rf9.txt","rf45.txt","refl_a_lf.txt","refl_b_lf.txt","pop_lf.txt","pop_a_sum.txt","pop_b_sum.txt","as_c_sum.txt","omc_a_sum.txt","omc_b_sum.txt","tr_x_a_sum.txt","tr_x_b_sum.txt","tr_y_a_sum.txt","tr_y_b_sum.txt"};
paths=dir<>#&/@files; *)
file1="rf_pwr_210512.hdf5";
path1=dir1<>file1;

hdir1=Import[path1,{"HDF5"}][[{29,35,32,41,44,38,11,14,2,5,8,17,20,23,26}]]
data1=Part[#,1;;9000]&/@Import[path1,{"HDF5",hdir1}];

Dimensions[data1]

cursors1={{1650,1940},{2450,2950},{3570,3820},{4120,4300},{4600,4950},{5250,5550},{7120,7250},{7700,7900},{8200,8400}};

ListPlot[data1[[{2,3}]],plotoptn[2],Joined->True,Prolog-> {{Gray,Rectangle[{#[[1]],-1*^6},{#[[2]],+1*^6}]}&/@cursors1}]

ListPlot[data1[[{4,5}]],plotoptn[2],Joined->True,Prolog-> {{Gray,Rectangle[{#[[1]],0},{#[[2]],+1000000}]}&/@cursors1}]

f[c_,d_]:=Mean[d[[#[[1]];;#[[2]]]]]&/@c
g[c_,d_]:=Transpose[{Mean/@c,f[c,d]}]
i1[c_,d_]:=Interpolation[g[c,d][[{1,3,5,7,9}]]]
i1[d_]:=i1[cursors1,d]
h1[c_,d_]:=MapThread[{i1[c,d][#2[[1]]],#2[[2]],ratio[((#2[[2]])/(i1[c,d][#2[[1]]])),#1]}&,{{(1/(Sqrt[2])),(Sqrt[2]),(1/(Sqrt[2])),(Sqrt[2])},g[c,d][[{2,4,6,8}]]}]
hh1[c_,d_]:=MapThread[{i1[c,d][#2[[1]]],#2[[2]],ratio[((#2[[2]])/(i1[c,d][#2[[1]]])),#1[[1]],#1[[2]]]}&,{{{rad45[24],rad45[21]},{rad45[24],rad45[27]},{rad9[20.4],rad9[17.4]},{rad9[20.4],rad9[23.4]}},g[c,d][[{2,4,6,8}]]}]

g[cursors1,data1[[2]]]

h1[cursors1,data1[[9]]]
hh1[cursors1,data1[[9]]]

Table shows percentage of RF power in 45MHz (columns 2 & 3), 9MHz (columns 4 & 5) and carrier (columns 6 & 7).
Columns 2, 4 & 6 are measured by lowering the modulation depth, whereas columns 3, 5 & 7 are measured by increasing it.
First column is nominal power/dBm readback

res1=hh1[cursors1,#]&/@data1;
pwr1=Mean/@Map[First,res1,{2}];
frac1={#[[1]],#[[2]],#[[3]],#[[4]],1-#[[1]]-#[[3]],1-#[[2]]-#[[4]]}&/@Map[Last,res1,{2}];
TableForm[MapThread[Prepend,{MapThread[Prepend,{frac1,pwr1}],names}]]

Plot[{Interpolation[data1[[4]],InterpolationOrder->1][x],i1[data1[[4]]][x]},{x,1000,9000},Evaluate[plotoptn[2]],Prolog-> {{Gray,Rectangle[{#[[1]],0},{#[[2]],+1000}]}&/@cursors1}]

Plot[{Interpolation[data1[[10]],InterpolationOrder->1][x],i1[data1[[10]]][x]},{x,1000,9000},Evaluate[plotoptn[2]],Prolog-> {{Gray,Rectangle[{#[[1]],0},{#[[2]],+1000}]}&/@cursors1}]

Plot[{Interpolation[data1[[9]],InterpolationOrder->1][x],i1[data1[[9]]][x]},{x,1000,9000},Evaluate[plotoptn[2]],Prolog-> {{Gray,Rectangle[{#[[1]],0},{#[[2]],+1000}]}&/@cursors1},PlotRange->{0,0.6}]

Measurements on April 17 2019, 00:30:00 UTC

alog 48595

dir2="E:\\OneDrive\\Documents\\Mathematica\\RFpower\\17Apr2019\\";
file2="rf_pwr_190417.hdf5";
path2=dir2<>file2;

hdir2=Import[path2,{"HDF5"}][[{10,12,11,14,15,13,4,5,1,2,3,6,7,8,9}]]
data2=Part[#,12500;;22500]&/@Import[path2,{"HDF5",hdir2}]{1,1,1,1,1,1,1,1,0.5,0.16,0.16,1,1,1,1};

Dimensions[data2]

cursors2={{2700,3700},{4050,4426},{4750,5650},{6110,6360},{6750,7750}};

ListPlot[data2[[{2,3}]],plotoptn[2],Joined->True,Prolog-> {{Gray,Rectangle[{#[[1]],-1*^6},{#[[2]],+1*^6}]}&/@cursors2},PlotRange->All]

i2[c_,d_]:=Interpolation[g[c,d][[{1,3,5}]],InterpolationOrder->2]
i2[d_]:=i2[cursors2,d]
h2[c_,d_]:=MapThread[{i2[c,d][#2[[1]]],#2[[2]],ratio[((#2[[2]])/(i2[c,d][#2[[1]]])),#1]}&,{{(10^(2/20)),(Sqrt[2])},g[c,d][[{2,4}]]}]
hh2[c_,d_]:=MapThread[{i2[c,d][#2[[1]]],#2[[2]],ratio[((#2[[2]])/(i2[c,d][#2[[1]]])),#1[[1]],#1[[2]]]}&,{{{rad45[24],rad45[26]},{rad9[20.4],rad9[23.4]}},g[c,d][[{2,4}]]}]

g[cursors2,data2[[2]]]

h2[cursors2,data2[[4]]]
hh2[cursors2,data2[[4]]]

Table shows percentage of RF power in 45MHz (column 2),  9MHz (column 3) and carrier (column 4)
First column is nominal power/dBm readback

res2=hh2[cursors2,#]&/@data2;
pwr2=Mean/@Map[First,res2,{2}];
frac2={#[[1]],#[[2]],1-#[[1]]-#[[2]]}&/@Map[Last,res2,{2}];
TableForm[MapThread[Prepend,{MapThread[Prepend,{frac2,pwr2}],names}]]

Plot[{Interpolation[data2[[4]],InterpolationOrder->1][x],i2[data2[[4]]][x]},{x,2000,9000},Evaluate[plotoptn[2]],PlotRange->All,Prolog->{{Gray,Rectangle[{#[[1]],0},{#[[2]],+1*^6}]}&/@cursors2}]

Plot[{Interpolation[data2[[9]],InterpolationOrder->1][x],i2[data2[[9]]][x]},{x,2000,9000},Evaluate[plotoptn[2]],PlotRange->All,Prolog->{{Gray,Rectangle[{#[[1]],0},{#[[2]],+1*^4}]}&/@cursors2}]

Compare Measurements

Ratios: New/Old

Table shows total power ratio between new and old (column 1), 45 MHz power ratio (column 2), 9 MHz power ratio (column 3), and carrier power ratio (column 4)

pwrratio=Drop[pwr1/pwr2,{2,3}];
sb1pwr=Part[#,{2,4,6}]&/@(pwr1 frac1);
sb2pwr=pwr2 frac2;
sbratio=Transpose[Drop[sb1pwr/sb2pwr,{2,3}]];
TableForm[Transpose[{Drop[names,{2,3}],pwrratio,Sequence @@sbratio}]]

Input-Power Normalized Ratios: New/Old

The total power in reflection has increased by 2.65 (shot noise x1.6), whereas the 9 MHz sidebands have increase by ~4.18 (signal x2.05). The carrier gain in the PRC is also 1.21 times higher (signal 1.1), yielding an improvement of the SNR of about 1.4 at equivalent input power, or ~1.6 with the increased input power.

At the AS port the total power stayed about the same for equivalent input power with carrier contribution decreasing by ~0.7-0.8, the 45 MHz contribution increasing by ~1.2, and the 9 MHz reducing by a factor of ~4-5.5. With the increase of the 9 MHz sideband gain of ~1.7 in the PRC, the 9 MHz contrast defect has improved by roughly 7-10.

From the estimated 320 mW at the AS port, 269 mW are 45 MHz sidebands, 32-46 mW are carrier and 4-5 mW are 9 MHz sidebands. With 23.3mW of the carrier in the TEM00, we end up with 9-23mW in carrier HOM. This is significantly better than with the old ITM, where the carrier TEM00 and HOM were about the same at a lower input power. Estimating 2.2 kW of carrier light at the beamsplitter, the carrier contrast defect is now about 13-32 ppm, where we had 20-66 pm previously. However 87 ppm are reported in alog 56590. The uncertainty is due to the rather inconsistent measurements coming from ASC-AS_C, OMC_A and OMC_B.

Table shows input-power normalized power ratio between new and old (column 1), 45 MHz power ratio (column 2), 9 MHz power ratio (column 3), and carrier power ratio (column 4)

pwrdoubleratio=(pwrratio/(pwrratio[[1]]));
sbdoubleratio=(sbratio/(pwrratio[[1]]));
TableForm[Transpose[{Drop[names,{2,3}],pwrdoubleratio,Sequence @@sbdoubleratio}]]

Power Levels New

alog 46386
Input efficiency from PSL to PRM: 88.8%
Loss in REFL path 28.4% with 4 50:50 and 1 90:10 beamsplitter. Overall efficiency: 1/223.
Estimate that about 10% of the incident carrier power is at the reflected port, ~25% of the 45MHz sidebands, and ~65% of the 9 MHz sidebands.

Table shows total power (column 1), 45 MHz power (column 2), 9 MHz power (column 3), and carrier power (column 4)

TableForm[Transpose[{Drop[names,{2,3}],Drop[pwr1,{2,3}],Sequence@@Transpose[Drop[sb1pwr,{2,3}]]}]]

Power Levels Old

Table shows total power (column 1), 45 MHz power (column 2), 9 MHz power (column 3), and carrier power (column 4)

TableForm[Transpose[{Drop[names,{2,3}],Drop[pwr2,{2,3}],Sequence@@Transpose[Drop[sb2pwr,{2,3}]]}]]